ESP8266 АЦП кнопки - прошу помочь

Подключение исполнительных устройств, датчиков, контроллеров.

Модератор: immortal

Ответить
C_3AXAPOB
Сообщения: 510
Зарегистрирован: Ср июн 08, 2016 4:17 pm
Благодарил (а): 124 раза
Поблагодарили: 101 раз

ESP8266 АЦП кнопки - прошу помочь

Сообщение C_3AXAPOB » Ср авг 22, 2018 1:39 pm

Здравствуйте!
Прошу помочь со скетчем для ESP8266.
Есть ESP8266 (nodemcu v.1).
К пину А0 через резисторный делитель подключены две кнопки и дачик открытия двери.
Руководствуясь примерами я написал скетч который обрабатывает полученные с АЦП значения и передает их по MQTT в Majordomo. Все работает. НО!
Никак не получается прикрутить обработку длительного нажатия кнопки которая управляет реле. По задумке одно -короткое нажатие включение/выключение реле №1. Длительное нажатие этой кнопки включение/выключение реле №2.


КОД:
СпойлерПоказать

Код: Выделить всё

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// Update these with values suitable for your network.

const char* ssid = "Agata";
const char* password = "Ilikechuckchuk";
const char* mqtt_server = "192.168.1.666";

#define relay1_mqtt "Agata01ard/relay_1"         //публикуемый топик
#define relay2_mqtt "Agata01ard/relay_2"         //публикуемый топик
#define doorstat_mqtt "Agata01ard/DoorStatus"         //публикуемый топик
#define doorbell_mqtt "Agata01ard/DoorBell"         //публикуемый топик
#define DHT_temp_mqtt "Agata01ard/temp"         //публикуемый топик
#define DHT_hum_mqtt "Agata01ard/hum"         //публикуемый топик
#define ir_mqtt "Agata01ard/ir"         //публикуемый топик

#define RELAY_1 5                            //Выход на реле #1
#define RELAY_2 14                            //Выход на реле #2
#define DHTPIN 4                             //Номер пина, к которому подсоединен датчик

#define DHTTYPE DHT22            // Задаём тип DHT датчика

int relay1_status = 0;
int relay2_status = 0;
int door_bell = 0;
int door_status = 0;


static char char_temp[10];      // Переменная для перевода из int в char
static char char_hum[10];

long last_relays = millis();                    //функция времени в милисекундах
long last_DHT = millis();                    //функция времени в милисекундах
long longpress = millis();                    //функция времени в милисекундах

int button = 0;
int pressed_button = 0;
int old_button = 0;

DHT dht(DHTPIN, DHTTYPE);

WiFiClient espClient;
PubSubClient client(espClient);
long lastMsg = 0;
char msg[50];
int value = 0;

void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");

  String strTopic = String(topic);
  String strPayload = String((char*)payload);

  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();

  if (strTopic == "Agata01ard/relay_1") {
    if ((char)payload[0] == '1') {
      digitalWrite(RELAY_1, false);
      relay1_status = 1;
    } else {
      digitalWrite(RELAY_1, true);
      relay1_status = 0;
    }
  }
  if (strTopic == "Agata01ard/relay_2") {
    if ((char)payload[0] == '1') {
      digitalWrite(RELAY_2, false);
      relay2_status = 1;
    } else {
      digitalWrite(RELAY_2, true);
      relay2_status = 0;
    }
  }

  if (strTopic == "Agata01ard/ir") {
    if ((char)payload[0] == '000') {
      Serial.println("IR command recived");
    }
  }


}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "Agata01ard";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish(relay1_mqtt, String(relay1_status).c_str());
      client.publish(relay2_mqtt, String(relay2_status).c_str());
      client.publish(DHT_temp_mqtt, char_temp); //отправляем в Брокер значения
      client.publish(DHT_hum_mqtt, char_hum);
      client.publish(ir_mqtt, "0");
      // ... and resubscribe
      client.subscribe(relay1_mqtt);
      client.subscribe(relay2_mqtt);
      client.subscribe(ir_mqtt);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}


void setup() {

  dht.begin();

  pinMode(RELAY_1, OUTPUT);                  //Выход на реле 1
  digitalWrite(RELAY_1, true);

  pinMode(RELAY_2, OUTPUT);                  //Выход на реле 2
  digitalWrite(RELAY_2, true);

  pinMode(A0, INPUT);


  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  delay(100);

  Serial.println(analogRead(A0));

  if (millis() - last_relays > 2000) {
    last_relays = millis();
    Serial.print("Publish message: ");
    Serial.println(String(relay1_status).c_str());
    Serial.println(String(relay2_status).c_str());
    client.publish(relay1_mqtt, String(relay1_status).c_str());
    client.publish(relay2_mqtt, String(relay2_status).c_str());
  }

  if (millis() - last_DHT > 600000)            //периодичность публикации топика
  {
    last_DHT = millis();
    Serial.print("DHT data send: ");
    client.publish(DHT_temp_mqtt, char_temp); //отправляем в Брокер значения
    client.publish(DHT_hum_mqtt, char_hum);
  }

  readDHT();
  processButtons();

}


void readDHT()
{
  int h = dht.readHumidity();     // Переменная типа int для Влажности
  int t = dht.readTemperature();  // Переменная типа int для Температуры
  dtostrf(t, 3, 0, char_temp);    // Перевод из int в char
  dtostrf(h, 3, 0, char_hum);
  if (isnan(t) || isnan(h))     // Проверка удачно ли прошло считывание с DHT22
  {
    Serial.println("Failed to read from DHT22");  // Не удалось прочитать DHT22
  }
}

int readADC(int pin)
{
  int i, sum, b, ADCval = 0;

  sum = 0;
  for (i = 0; i < 3; i++)
  {
    sum += analogRead(pin);
  }
  ADCval = sum / 3;
  if (ADCval < 830) b = 0;
  else if (ADCval > 989 && ADCval < 1000) b = 1; //Кнопка реле
  else if (ADCval > 1020 && ADCval < 1030) b = 2; //дверной звонок
  else if (ADCval > 900 && ADCval < 920) b = 3; //Дверь открыта
  else if (ADCval > 820 && ADCval < 845) b = 4; //Дверь закрыта
  else b = 0;
  return b;
}


void processButtons() {

  button = readADC(0);

  if (button == 1) {
    longpress = millis();
    if (millis() - longpress >= 500)
    {
      button = 5;
    }
  }

    if (old_button == button) {
      old_button = button;
      pressed_button = 0;
    }

    else {
      old_button = button;
      pressed_button = button;
    }

    if (pressed_button == 1) {

      Serial.println("Button1");

      if (relay1_status == 1)
      {
        digitalWrite(RELAY_1, true);
        relay1_status = 0;
        client.publish(relay1_mqtt, String(relay1_status).c_str());
      } else {
        digitalWrite(RELAY_1, false);
        relay1_status = 1;
        client.publish(relay1_mqtt, String(relay1_status).c_str());
      }
    }
    if (pressed_button == 2)
    {
      door_bell = 1;
      client.publish(doorbell_mqtt, String(door_bell).c_str());
      door_bell = 0;
    }

    if (pressed_button == 3)
    {
      Serial.println("Door closed");
      door_status = 0;
      client.publish(doorstat_mqtt, String(door_status).c_str());
    }

    if (pressed_button == 4)
    {
      Serial.println("Door opened");
      door_status = 1;
      client.publish(doorstat_mqtt, String(door_status).c_str());
    }

    if (pressed_button == 5)
    {
      Serial.println("Long press button 1");
      if (relay2_status == 1)
      {
        digitalWrite(RELAY_2, true);
        relay2_status = 0;
        client.publish(relay2_mqtt, String(relay2_status).c_str());
      } else {
        digitalWrite(RELAY_2, false);
        relay2_status = 1;
        client.publish(relay2_mqtt, String(relay2_status).c_str());
      }

    }

  }
Orange pi pc plus, megaD-2561, Xiaomi
--------------------------------------------------
http://connect.smartliving.ru/profile/908
C_3AXAPOB
Сообщения: 510
Зарегистрирован: Ср июн 08, 2016 4:17 pm
Благодарил (а): 124 раза
Поблагодарили: 101 раз

Re: ESP8266 АЦП кнопки - прошу помочь

Сообщение C_3AXAPOB » Чт авг 23, 2018 1:04 am

Проблема решена. Готовое решение ниже. Вдруг кому-то понадобится. Итого сэкономлено три цифровых пина еспешки.
СпойлерПоказать

Код: Выделить всё

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <DHT.h>

// Update these with values suitable for your network.

const char* ssid = "Agata";
const char* password = "Pizza";
const char* mqtt_server = "192.168.1.666";

#define relay1_mqtt "Agata01ard/relay_1"         //публикуемый топик
#define relay2_mqtt "Agata01ard/relay_2"         //публикуемый топик
#define doorstat_mqtt "Agata01ard/DoorStatus"         //публикуемый топик
#define doorbell_mqtt "Agata01ard/DoorBell"         //публикуемый топик
#define DHT_temp_mqtt "Agata01ard/temp"         //публикуемый топик
#define DHT_hum_mqtt "Agata01ard/hum"         //публикуемый топик
#define ir_mqtt "Agata01ard/ir"         //публикуемый топик

#define RELAY_1 5                            //Выход на реле #1
#define RELAY_2 14                            //Выход на реле #2
#define DHTPIN 4                             //Номер пина, к которому подсоединен датчик

#define DHTTYPE DHT22            // Задаём тип DHT датчика

int relay1_status = 0;
int relay2_status = 0;
int door_bell = 0;
int door_status = 0;

//===================================ТЕМПЕРАТУРА========================================//
static char char_temp[10];      // Переменная для перевода из int в char
static char char_hum[10];

//===================================ТАЙМЕРЫ========================================//
long last_relays = millis();                    //функция времени в милисекундах
long last_DHT = millis();                    //функция времени в милисекундах

//===================================ПЕРЕМЕННЫЕ ДЛЯ КНОПОК========================================//
byte lastButtonPress = 0; // this variable used for debouncing
unsigned long lastButtonTime = 0; // this variable used to enforce a delay between samples
byte repeatedButtonPress = 0; // this variable used to disallow the user holding a button down and sending zillions of button press events
int SHORT_BC = 0;


DHT dht(DHTPIN, DHTTYPE);

WiFiClient espClient;
PubSubClient client(espClient);
long lastMsg = 0;
char msg[50];
int value = 0;

void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void callback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Message arrived [");
  Serial.print(topic);
  Serial.print("] ");

  String strTopic = String(topic);
  String strPayload = String((char*)payload);

  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();

  if (strTopic == "Agata01ard/relay_1") {
    if ((char)payload[0] == '1') {
      digitalWrite(RELAY_1, false);
      relay1_status = 1;
    } else {
      digitalWrite(RELAY_1, true);
      relay1_status = 0;
    }
  }
  if (strTopic == "Agata01ard/relay_2") {
    if ((char)payload[0] == '1') {
      digitalWrite(RELAY_2, false);
      relay2_status = 1;
    } else {
      digitalWrite(RELAY_2, true);
      relay2_status = 0;
    }
  }

  if (strTopic == "Agata01ard/ir") {
    if ((char)payload[0] == '000') {
      Serial.println("IR command recived");
    }
  }


}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "Agata01ard";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish(relay1_mqtt, String(relay1_status).c_str());
      client.publish(relay2_mqtt, String(relay2_status).c_str());
      client.publish(DHT_temp_mqtt, char_temp); //отправляем в Брокер значения
      client.publish(DHT_hum_mqtt, char_hum);
      client.publish(ir_mqtt, "0");
      // ... and resubscribe
      client.subscribe(relay1_mqtt);
      client.subscribe(relay2_mqtt);
      client.subscribe(ir_mqtt);
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}


void setup() {

  dht.begin();

  pinMode(RELAY_1, OUTPUT);                  //Выход на реле 1
  digitalWrite(RELAY_1, true);

  pinMode(RELAY_2, OUTPUT);                  //Выход на реле 2
  digitalWrite(RELAY_2, true);

  pinMode(A0, INPUT);


  Serial.begin(115200);
  setup_wifi();
  client.setServer(mqtt_server, 1883);
  client.setCallback(callback);
}

void loop() {

  if (!client.connected()) {
    reconnect();
  }
  client.loop();

  delay(100);

    if (millis() - last_relays > 2000) {
    last_relays = millis();
    Serial.print("Publish message: ");
    Serial.println(String(relay1_status).c_str());
    Serial.println(String(relay2_status).c_str());
    client.publish(relay1_mqtt, String(relay1_status).c_str());
    client.publish(relay2_mqtt, String(relay2_status).c_str());
  }

  if (millis() - last_DHT > 600000)            //периодичность публикации топика
  {
    last_DHT = millis();
    Serial.print("DHT data send: ");
    client.publish(DHT_temp_mqtt, char_temp); //отправляем в Брокер значения
    client.publish(DHT_hum_mqtt, char_hum);
  }

  readDHT();
  processButtons();

}


void readDHT()
{
  int h = dht.readHumidity();     // Переменная типа int для Влажности
  int t = dht.readTemperature();  // Переменная типа int для Температуры
  dtostrf(t, 3, 0, char_temp);    // Перевод из int в char
  dtostrf(h, 3, 0, char_hum);
  if (isnan(t) || isnan(h))     // Проверка удачно ли прошло считывание с DHT22
  {
    Serial.println("Failed to read from DHT22");  // Не удалось прочитать DHT22
  }
}

byte getButtonPress() {

  if (millis() - lastButtonTime < 10) // if we already sampled less than 10ms ago,
    return (0); //  give the resistor ladder voltage more time to stabilize

  lastButtonTime = millis(); // grab a fresh timestamp so that next time we're called, we avoid sampling again too soon
  byte thisButtonPress = 0; // a place to hold the button press result this time around
  int sensorValue = analogRead(A0); // grab a reading from our resistor-ladder of buttons

  if (sensorValue < 830) { // no button was pressed
    lastButtonPress = 0;
    return (0); // don't do anything, since no button was pressed
  }
  else if (sensorValue > 985 && sensorValue < 1000) // button 1 was pressed
    thisButtonPress = 1;
  else if (sensorValue > 1020 && sensorValue < 1030) // button 2 was pressed
    thisButtonPress = 2;
  else if (sensorValue > 900 && sensorValue < 920) { // button 3 was pressed
    thisButtonPress = 3;
    if (SHORT_BC > 0 && SHORT_BC < 7) {
      SHORT_BC = 0;
      return thisButtonPress = 5;
    }
    if (SHORT_BC >= 8) {
      SHORT_BC = 0;
      return thisButtonPress = 6;
    }
  }
  else if (sensorValue > 820 && sensorValue < 845) { // button 4 was pressed
    thisButtonPress = 4;

    if (SHORT_BC > 0 && SHORT_BC < 7) {
      SHORT_BC = 0;
      return thisButtonPress = 5;
    }
    if (SHORT_BC >=8) {
      SHORT_BC = 0;
      return thisButtonPress = 6;
    }
  }
  else                        // button 4 was pressed
    thisButtonPress = 0;


  if (thisButtonPress == 1) {
    SHORT_BC++;                   //  увеличить счетчик кратковременных нажатий
  } else {
    if (thisButtonPress == repeatedButtonPress) {
      return (0); // so do nothing
    }
  }

  if (thisButtonPress == lastButtonPress) { // the same button was pressed at least two samples in a row
    repeatedButtonPress = thisButtonPress; // keep track of this, so we never fire again on the this press
    Serial.print("Sensor value: ");
    Serial.print(sensorValue);
    return (thisButtonPress); // finally, fire!
  }
  else { // we got a different button than last time, so wait for the next sample to match before we fire any event
    lastButtonPress = thisButtonPress; // remember this press to compare to our next sample
    repeatedButtonPress = 0; // no buttons were held down, so there was no repeat
  }
  return (0); // for some reason adding this in makes our sketch 2 bytes SMALLER?!
}


void processButtons() {
  byte buttonPress = getButtonPress();

  if (buttonPress == 5) {

    Serial.println("Switch short click");

    if (relay1_status == 1)
    {
      digitalWrite(RELAY_1, true);
      relay1_status = 0;
      client.publish(relay1_mqtt, String(relay1_status).c_str());
    } else {
      digitalWrite(RELAY_1, false);
      relay1_status = 1;
      client.publish(relay1_mqtt, String(relay1_status).c_str());
    }
  }

  if (buttonPress == 2)
  {
    door_bell = 1;
    client.publish(doorbell_mqtt, String(door_bell).c_str());
    door_bell = 0;
  }

  if (buttonPress == 3)
  {
    Serial.println("Door closed");
    door_status = 0;
    client.publish(doorstat_mqtt, String(door_status).c_str());
  }

  if (buttonPress == 4)
  {
    Serial.println("Door opened");
    door_status = 1;
    client.publish(doorstat_mqtt, String(door_status).c_str());
  }

  if (buttonPress == 6)
  {
    Serial.println("Switch long press");
    if (relay2_status == 1)
    {
      digitalWrite(RELAY_2, true);
      relay2_status = 0;
      client.publish(relay2_mqtt, String(relay2_status).c_str());
    } else {
      digitalWrite(RELAY_2, false);
      relay2_status = 1;
      client.publish(relay2_mqtt, String(relay2_status).c_str());
    }

  }
 Serial.print(", button pressed: ");
    Serial.println(buttonPress);
    Serial.print("Counter ");
    Serial.println(SHORT_BC);
}
Orange pi pc plus, megaD-2561, Xiaomi
--------------------------------------------------
http://connect.smartliving.ru/profile/908
Ответить